EnigmA Amiga Run 1996 February/EnigmA AMIGA RUN 04 (1996)(G.R. Edizioni)(IT)[!][issue 1996-02][Skylink CD III].iso/earcd/editor/proged10.lha/InstallProgED/Install

Text File | 1995-08-30 | 15KB | 832 lines

;
; ProgED Installer Utility
;
; This script is Copyright ©1995 Giovanni Lambiase
;

(
    ; Setup English default strings

    (set #intro
        (cat
            "ProgED V1.0 - All Rights Reserved.\n"
            "\n"
            "ProgED  ©'95 Giovanni Lambiase\n"
            "Reqtools.library - Copyright Nico François\n"
            "Powerpacker.library - Copyright Nico François\n"
            "XpkMaster.library - Copyright Urban Dominik Müller & Bryan Ford\n"
            "\n"
            "ProgED is NOT 'freely distributable' but SHAREWARE.\n"
            "Look at the licence file before installing ProgED.\n"
            "Installing this software means\naccepting that licence.\n"
            "Thank you.\n"
        )
    )

    (set #badkick "\n Sorry, this package requires OS v2.04 or better.\n")

    (set #askdir
        (cat    "Select where you would like to install "
            "ProgED. A drawer called 'ProgED' will "
            "be created here."
        )
    )

    (set #askdir_help
        (cat
            "ProgED and all necessary files will be installed "
            "in the directory of your choice. You may wish "
            "to create a new directory for ProgED by using "
            "the 'Make New Drawer' gadget.\n\n"
            "You may install this version over your existing "
            "version of ProgEd, but you will loose your "
            "current preference settings and some of your "
            "files may be overwritten with more recent "
            "versions. This may be undesirable if you have "
            "customised your enviroment."
        )
    )

    (set #overwrite    "The 'ProgED' directory already exists, overwrite?")

    (set #overwrite_help
        (cat
            "You may stop the install to "
            "avoid overwriting your current "
            "version of ProgED.\n\n"
            "Continuing the install will "
            "overwrite your current files "
            "and you will loose your current "
            "preferences."
        )
    )

    (set #yes "Yes")

    (set #no "No")

    (set #quit "Quit")

    (set #havemwb "Do you have MagicWB installed on your system ?")

    (set #havemsb_help
        (cat
            "MagicWB is an icon package by Martin Huttenloher "
            "(© 1993). MagicWB icons looks 3D, 8 colors, ecc. "
            "If you haven't it look at your BBS to download "
            "1.2 PD version."
        )
    )

    (set #installed "ProgED will be installed in ")

    (set #installing "Installing ProgED Program...")

    (set #creating "Creating 'ProgED' directory")

    (set #copyingexe "Copying ProgED executable...")

    (set #copyingexeprt "Copying PED_Print executable...")

    (set #copyingman "Copying Manual...")

    (set #crticonsdir "Creating 'Icons' directory")

    (set #crtprjdir "Creating 'Projects' directory")

    (set #crtclientsdir "Creating 'Clients' directory")

    (set #crtfoldersdir "Creating 'Folders' directory")

    (set #crtscannersdir "Creating 'Scanners' directory")

    (set #crtmacrosdir "Creating 'Macros' directory")

    (set #crtcatalogsdir "Creating 'Catalogs' directory")

    (set #crtldir "Creating 'L' directory")

    (set #crtsasc "Creating 'SASC_Support' directory")

    (set #crtsources "Creating 'Sources' directory")

    (set #thanks "Thanks for registering. Supporting shareware's authors is Amiga's future!")

    (set #nokeyfile
        (cat
            "No keyfile was found during "
            "installation. For details of how to register "
            "and receive the full version, refer to the "
            "documentation."
        )
    )

    (set #reset
        (cat
            "\n\nWhen this installation stops remember that you MUST "
            "reset your Amiga to properly setup ProgED enviroment!"
        )
    )

    (set #setup1
        (cat
            "To properly setup ProgED I have to modify your "
            "User-StartUp adding following command:\n\n"
        )
    )

    (set #setup2
        (cat
            "If you skip this pass you MUST manually enter "
            "it later."
        )
    )

    (set #setup_help
        (cat
            "ProgED needs an Assign in main directory to "
            "properly setup. If you skip this pass you MUST "
            "manually enter it later in your User-StartUp or "
            "in a shell prior to run ProgED."
        )
    )

    ; If language is italian then ...

    (if (= @language "italiano")
    (
    ; Setup Italian strings

    (set #intro
        (cat
            "ProgED V1.0 - All Rights Reserved.\n"
            "\n"
            "ProgED  ©'95 Giovanni Lambiase\n"
            "Reqtools.library - Copyright Nico François\n"
            "Powerpacker.library - Copyright Nico François\n"
            "XpkMaster.library - Copyright Urban Dominik Müller & Bryan Ford\n"
            "\n"
            "ProgED NON E' 'liberamente distribuibile' ma\n"
            "SHAREWARE. Leggi il file di licenza prima di\n"
            "iniziare l'installazione. Installare questo\n"
            " software significa accettare quella licenza.\n"
            "Grazie.\n"
        )
    )

    (set #badkick "\n Spiacente, questo pacchetto richiede il sistema operativo OS v2.04 o superiori.\n")

    (set #askdir
        (cat    "Selezione dove vuoi installare ProgED. "
            "Un nuovo cassetto chiamato 'ProgED' sarà "
            "creato dove specificato."
        )
    )

    (set #askdir_help
        (cat
            "ProgED e tutti i file necessari saranno installati "
            "nella directory scelta. Puoi creare un nuovo cassetto "
            "per ProgED usando il gadget 'Crea nuovo cassetto'.\n\n"
            "Puoi installare questa versione sovrascrivendo "
            "una precedente versione di ProgEd, ma perderai le "
            "preferenze e qualcuno dei tuoi file sarà sovrascritto "
            "con uno più recente. Questo può essere indesiderabile "
            "se hai già un ambiente adattato ai tuoi gusti."
        )
    )

    (set #overwrite "Il cassetto 'ProgED' esiste già, lo sovrascrivo ?")

    (set #overwrite_help
        (cat
            "Puoi fermare l'installazione per "
            "evitare la sovrascrittura della "
            "versione corrente di ProgED.\n\n"
            "Continuare l'installazione sovrascriverà "
            "i file correnti e perderai le preferenze "
            "correnti."
        )
    )

    (set #yes "Si")

    (set #no "No")

    (set #quit "Esci")

    (set #havemwb "Hai MagicWB installato sul tuo sistema ?")

    (set #havemsb_help
        (cat
            "MagicWB è un package di icone creato da Martin Huttenloher "
            "(© 1993). Le icone di MagicWB sono tridimensionali, hanno "
            "8 colors, ecc. Se non hai ancora installato MagicWB cerca "
            "nella tua BBS la versione 1.2 PD e scaricala."
        )
    )

    (set #installed "ProgED sarà installato in ")

    (set #installing "Sto installando il ProgED ...")

    (set #creating "Sto creando il cassetto 'ProgED'")

    (set #copyingexe "Sto copiano l'eseguibile del ProgED ...")

    (set #copyingexeprt "Sto copiando l'eseguibile del PED_Print ...")

    (set #copyingman "Sto copiano il manuale ...")

    (set #crticonsdir "Sto creando il cassetto 'Icons'")

    (set #crtprjdir "Sto creando il cassetto 'Projects'")

    (set #crtclientsdir "Sto creando il cassetto 'Clients'")

    (set #crtfoldersdir "Sto creando il cassetto 'Folders'")

    (set #crtscannersdir "Sto creando il cassetto 'Scanners'")

    (set #crtmacrosdir "Sto creando il cassetto 'Macros'")

    (set #crtcatalogsdir "Sto creando il cassetto 'Catalogs'")

    (set #crtldir "Sto creando il cassetto 'L'")

    (set #crtsasc "Sto creando il cassetto 'SASC_Support'")

    (set #thanks "Grazie per esserti registrato. Aiutare gli autori di software shareware è il futuro di Amiga!")

    (set #nokeyfile
        (cat
            "Nessun keyfile trovato durante l'installazione. "
            "Per i dettagli riguardo la registrazione e su come "
            "ricevere una versione pienamente funzionante leggi "
            "la documentazione allegata."
        )
    )

    (set #reset
        (cat
            "\n\nQuando questa installazione sarà terminata ricorda "
            "che DEVI resettare il tuo Amiga per preparare propriamente "
            "l'ambiente del ProgED!"
        )
    )

    (set #setup1
        (cat
            "Per preparare l'ambiente del ProgED DEVO modificare la tua "
            "User-StartUp aggiungendo il seguente comando:\n\n"
        )
    )

    (set #setup2    "Se salti questo passo DOVRAI inserirlo manualmente più tardi.")

    (set #setup_help
        (cat
            "ProgED necessita di un assegnamento alla sua directory "
            "principale al fine di funzionare correttamente. Se "
            "salti questo passo DOVRAI inserirlo manualmente nella "
            "tua User-StartUp o in una shell prima di eseguire il ProgED."
        )
    )))





    (message #intro)

    ; sure we are running under a 2.04 ROM ?

    (if (< (/ (getversion) 65536) 37)
        (
            (message #badkick)
            (exit (quiet))
        )
    )


    ; Ask where to install it...

    (set destdir
        (askdir
            (prompt #askdir)
            (help #askdir_help)
            (default @default-dest)
            (disk)
        )
    )

    (set destdir
        (tackon destdir "ProgED")
    )

    (set @default-dest destdir)

    ; See whether this directory exists, if so warn the user

    (if (exists @default-dest)
        (
            (if (= 0 (askbool
                    (prompt #overwrite)
                    (help #overwrite_help)
                    (choices #yes #quit)
                ))

                (

                ; User wishes to quit

                (exit (quiet))
                )

            )
        )
    )

    ; Ask user if he wants MagicWB icons
    ; and figure out where pick up icons

    (if
        (askbool
            (prompt #havemwb)
            (help #havemsb_help)
            (choices #yes #no)
        )
        (set insticonsdir "Icons/MagicWB")
        (set insticonsdir "Icons/Standard")
    )

    ; Prompt for choosed dir

    (message #installed @default-dest)

    ; Start!

    (complete 0)

    (working #installing)

    ; Create the directory if it doesn't exist

    (if (= 0 (exists @default-dest))
        (
            (makedir @default-dest
                (prompt #creating)
                (infos)
            )
        )
    )

    (working #copyingexe)

    ; Install the PED executable file

    (copyfiles
        (source "PED")
        (dest @default-dest)
    )

    (copyfiles
        (source (tackon insticonsdir "PED.info"))
        (dest @default-dest)
    )

    (complete 20)

    (working #copyingexeprt)

    ; Install the PED_Print executable file

    (copyfiles
        (source "PED_Print")
        (dest @default-dest)
    )

    (copyfiles
        (source (tackon insticonsdir "PED_Print.info"))
        (dest @default-dest)
    )

    (complete 25)

    (working #copyingman)

    ; Install the Manual

    (copyfiles
        (source "Manual")
        (dest @default-dest)
    )

    (copyfiles
        (source (tackon insticonsdir "Manual.info"))
        (dest @default-dest)
    )

    (complete 30)

    (working #crticonsdir)

    ; Create icons' dir

    (set iconsdir (tackon @default-dest "Icons"))

    (if (= 0 (exists iconsdir))
        (
            (makedir iconsdir)

            (copyfiles
                (source (tackon insticonsdir "Icons.info"))
                (dest @default-dest)
            )
        )
    )

    ; Copy all icons

    (copyfiles
        (source (tackon insticonsdir "Icons"))
        (dest iconsdir)
        (all)
    )

    (complete 35)

    (working #crtprjdir)

    ; Create projects' dir

    (set projectsdir (tackon @default-dest "Projects"))

    (if (= 0 (exists projectsdir))
        (
            (makedir projectsdir)

            (copyfiles
                (source (tackon insticonsdir "Projects.info"))
                (dest @default-dest)
            )
        )
    )

    ; Copy all examples projects

    (foreach "Projects" "#?"
        (copyfiles
            (source (tackon "Projects" @each-name))
            (dest projectsdir)
        )

        (copyfiles
            (source (tackon insticonsdir "Icons/def_Project.info"))
            (dest projectsdir)
            (newname (cat (tackon projectsdir @each-name) ".info"))
        )
    )

    (complete 45)

    (working #crtclientsdir)

    ; Create clients' dir

    (set clientsdir (tackon @default-dest "Clients"))

    (if (= 0 (exists clientsdir))
        (
            (makedir clientsdir)

            (copyfiles
                (source (tackon insticonsdir "Clients.info"))
                (dest @default-dest)
            )
        )
    )

    ; Copy all examples clients

    (foreach "Clients" "PED_#?"
        (copyfiles
            (source (tackon "Clients" @each-name))
            (dest clientsdir)
            (files)
        )

        (copyfiles
            (source (tackon insticonsdir "Icons/def_Client.info"))
            (dest clientsdir)
            (newname (cat (tackon clientsdir @each-name) ".info"))
            (files)
        )
    )

    (copyfiles
        (source "Clients/DocksImages")
        (dest (tackon clientsdir "DocksImages"))
        (all)
    )

    (copyfiles
        (source "Clients/Docks.Prefs")
        (dest clientsdir)
    )

    (complete 55)

    (working #crtfoldersdir)

    ; Create folders' dir

    (set foldersdir (tackon @default-dest "Folders"))

    (if (= 0 (exists foldersdir))
        (
            (makedir foldersdir)

            (copyfiles
                (source (tackon insticonsdir "Folders.info"))
                (dest @default-dest)
            )
        )
    )

    ; Copy all examples folders

    (foreach "Folders" "#?"
        (copyfiles
            (source (tackon "Folders" @each-name))
            (dest foldersdir)
        )

        (copyfiles
            (source (tackon insticonsdir "Icons/def_FuncFolder.info"))
            (dest foldersdir)
            (newname (cat (tackon foldersdir @each-name) ".info"))
        )
    )

    (complete 60)

    (working crtscannersdir)

    ; Create scanners' dir

    (set scannersdir (tackon @default-dest "Scanners"))

    (if (= 0 (exists scannersdir))
        (
            (makedir scannersdir)

            (copyfiles
                (source (tackon insticonsdir "Scanners.info"))
                (dest @default-dest)
            )
        )
    )

    ; Copy all examples scanners

    (foreach "Scanners" "#?"
        (copyfiles
            (source (tackon "Scanners" @each-name))
            (dest scannersdir)
        )

        (copyfiles
            (source (tackon insticonsdir "Icons/def_Scanner.info"))
            (dest scannersdir)
            (newname (cat (tackon scannersdir @each-name) ".info"))
        )
    )

    (complete 65)

    (working crtmacrosdir)

    ; Create macros' dir

    (set macrosdir (tackon @default-dest "Macros"))

    (if (= 0 (exists macrosdir))
        (
            (makedir macrosdir)

            (copyfiles
                (source (tackon insticonsdir "Macros.info"))
                (dest @default-dest)
            )
        )
    )

    ; Copy all examples macros

    (foreach "Macros" "#?"
        (copyfiles
            (source (tackon "Macros" @each-name))
            (dest macrosdir)
        )

        (copyfiles
            (source (tackon insticonsdir "Icons/def_Arexx.info"))
            (dest macrosdir)
            (newname (cat (tackon macrosdir @each-name) ".info"))
        )
    )

    (complete 70)

    (working #crtcatalogsdir)

    ; Create Catalogs dir

    (set catalogsdir (tackon @default-dest "Catalogs"))

    (if (= 0 (exists catalogsdir))
        (
            (makedir catalogsdir)
        )
    )

    ; Copy all catalogs dir

    (copyfiles
        (source "Catalogs")
        (dest catalogsdir)
        (all)
    )

    (complete 75)

    (working crtldir)

    ; Create L dir

    (set ldir (tackon @default-dest "L"))

    (if (= 0 (exists ldir))
        (
            (makedir ldir)
        )
    )

    ; Copy all handlers

    (copyfiles
        (source "L")
        (dest ldir)
        (all)
    )

    (complete 80)

    (working #crtsasc)

    ; Create SASC_Support dir

    (set sascdir (tackon @default-dest "SASC_Support"))

    (if (= 0 (exists sascdir))
        (
            (makedir sascdir)
        )
    )

    ; Copy all files

    (copyfiles
        (source "SASC_Support")
        (dest sascdir)
        (all)
    )

    (complete 85)

    (working #crtsources)

    ; Create sources dir

    (set sourcesdir (tackon @default-dest "Sources"))

    (if (= 0 (exists sourcesdir))
        (
            (makedir sourcesdir)
        )
    )

    ; Copy all files

    (copyfiles
        (source "Sources")
        (dest sourcesdir)
        (all)
    )

    (complete 90)

    ; Copy keyfile if it exists

    (if (exists "KeyFile")
        (
            (copyfiles
                (source "KeyFile")
                (dest @default-dest)
            )

            (set foundkeyfile (cat #thanks))
        )

        ; Else, note we didn't find one

        (
            (set foundkeyfile (cat #nokeyfile))
        )
    )

    (set foundkeyfile
        (cat foundkeyfile #reset)
    )

    (complete 95)

    ; Copy EnvArc's file

    (set envarcdir "ENVARC:PED")

    (if (= 0 (exists envarcdir))
        (
            (makedir envarcdir)
        )
    )

    (copyfiles
        (source "EnvArc")
        (dest envarcdir)
        (all)
    )

    ; Copy Presets' file

    (set presetsdir (tackon @default-dest "Presets"))

    (if (= 0 (exists presetsdir))
        (
            (makedir presetsdir)
        )
    )

    (copyfiles
        (source "Presets")
        (dest presetsdir)
        (all)
    )

    ; Copy Handlers' files

    (set handlersdir "DEVS:DosDrivers")

    (if (= 0 (exists handlersdir))
        (
            (makedir handlersdir)
        )
    )

    (foreach "Devs" "#?"
        (copyfiles
            (source (tackon "Devs" @each-name))
            (dest handlersdir)
        )

        (copyfiles
            (source (tackon insticonsdir "Icons/def_Handler.info"))
            (dest handlersdir)
            (newname (cat (tackon handlersdir @each-name) ".info"))
        )
    )

    ; Updates User-StartUp

    (startup "ProgED"
        (prompt
            (cat
                #setup1
                "Assign ProgED: \"" @default-dest "\"\n\n"
                #setup2
            )
        )
        (help #setup_help)
        (command
            "Assign ProgED: \"" @default-dest "\"\n"
        )
    )

    (complete 100)

    ; Say goodbye

    (message foundkeyfile)
)